source: mauRepo/ISO19136-AnxE/test-026.xq @ 8191

xquery version "1.0";
(:~~~~~~~~~~~~~~~~~~~~~~~~~~ Conformance Test  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
Test Number:    026
Description:    A composition association shall not be tagged
                                inlineOrByReference="byReference" or
                                inlineOrByReference="inlineOrByReference".
Reference:              
~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~:)

import module namespace mod-fr = "urn:local-module:ISO19136-V3.2-AnxE_XMI-V1.1:framework"
at "#{ROOT_URL}ISO19136-AnxE/modules/module-framework-functions.xq";

import module namespace mod-xp = "urn:local-module:ISO19136-V3.2-AnxE_XMI-V1.1:xmi-proc"
at "#{ROOT_URL}ISO19136-AnxE/modules/module-xproc-functions.xq";

declare namespace UML   = "omg.org/UML1.3";
declare namespace cr    = "http://ndg.service.newmoon.conftest-result/1.0";

(: Declare local variables, particular to this test :)
declare variable $test-num as xs:integer := 26;
declare variable $pass-msg as xs:string := "The inlineOrByReference tagged value have been used correctly on all composition associations.";
declare variable $fail-msg as xs:string := "The test has failed because:";

(:
        #Date:          2009-01-15
        #Author:        Pavel Golodoniuc
        
        Declare the local assert function which defines a postive condition for pass.
:)
declare function local:assert($doc-root as node()?) as node()?
{
        let 
                $fail := (
                        for $end in $doc-root//UML:AssociationEnd[@aggregation eq "composite"]
                        let $tag := ($end/following-sibling::UML:AssociationEnd | $end/preceding-sibling::UML:AssociationEnd)/UML:ModelElement.taggedValue/UML:TaggedValue[@tag eq "inlineOrByReference" and @value ne "inline"]
                        where exists($tag)
                        return <cr:message>{ concat("Composition ", mod-xp:verbose-association($tag/../../../..), " should not be tagged inlineOrByReference=&quot;", $tag/@value, "&quot;.") }</cr:message>
                )
        return
                if (empty($fail)) then ()
                else
                        <cr:fail>
                                <cr:messages>{ $fail }</cr:messages>
                        </cr:fail>      
};

(: Create a new result element :)
mod-fr:new-result($test-num, $pass-msg, $fail-msg, local:assert(/))