source: mauRepo/ISO19136-AnxE/test-012.xq @ 8191

xquery version "1.0";
(:~~~~~~~~~~~~~~~~~~~~~~~~~~ Conformance Test  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
Test Number:    012
Description:    Assert uniqueness of sequenceNumber across all attributes
                                and association ends of class.
Reference:              
~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~:)

import module namespace mod-fr = "urn:local-module:ISO19136-V3.2-AnxE_XMI-V1.1:framework"
at "#{ROOT_URL}ISO19136-AnxE/modules/module-framework-functions.xq";

import module namespace mod-xp = "urn:local-module:ISO19136-V3.2-AnxE_XMI-V1.1:xmi-proc"
at "#{ROOT_URL}ISO19136-AnxE/modules/module-xproc-functions.xq";

declare namespace UML   = "omg.org/UML1.3";
declare namespace cr    = "http://ndg.service.newmoon.conftest-result/1.0";

(: Declare local variables, particular to this test :)
declare variable $test-num as xs:integer := 12;
declare variable $pass-msg as xs:string := "Each "sequenceNumber" tagged value is unique in the scope of the class owning the property.";
declare variable $fail-msg as xs:string := "The model contains non-unique sequenceNumber as follow:";

(: Declare the local assert function which defines a postive condition for pass :)
declare function local:assert($doc-root as node()?) as node()?
{
        let $fail := (
                for $class in $doc-root//UML:Class
                        let $seq := local:get-class-sequence-numbers($class)
                        for $dup in mod-xp:get-duplicates($seq/@value)
                        return
                                for $el in $seq[@value eq $dup]
                                let $nodename := string(node-name($el/../..))
                                return
                                        <cr:message>
                                        {
                                                (: Display descriptive error information :)
                                                if ($nodename eq "UML:Attribute") then
                                                        concat("The sequenceNumber=&quot;", $el/@value, "&quot; for attribute &quot;", $el/../../@name, "&quot; on class &quot;", $class/@name, "&quot; duplicates another sequence number in the same scope.")
                                                else
                                                        concat("The sequenceNumber=&quot;", $el/@value, "&quot; for association end with rolename &quot;", $el/../../@name, "&quot; from class &quot;", $class/@name, "&quot; duplicates another sequence number in the same scope.")
                                        }
                                        </cr:message>
        )
        return
                if (empty($fail)) then ()
                else
                        <cr:fail>
                                <cr:messages>{ $fail }</cr:messages>
                        </cr:fail>
};

(: Retrieve all sequenceNumber tagged values which belong to the class' attributes and association ends :)
declare function local:get-class-sequence-numbers($class as node()) as node()*
{
        (: Retrieve sequenceNumber tagged values of attributes of the class :)
        $class//UML:Attribute//UML:TaggedValue[@tag eq "sequenceNumber"],

        (: Retrieve sequenceNumber tagged values of association ends of the class :)
        //UML:Association//UML:AssociationEnd[
                (preceding-sibling::* | following-sibling::*)[@type eq $class/@xmi.id] and
                .//UML:TaggedValue[
                        @tag[matches(., "^(dest|source)style$")] and
                        (
                                @value[contains(., "Navigable=Navigable;")] or
                                count(ancestor::UML:Association.connection//UML:AssociationEnd) eq
                                        count(ancestor::UML:Association.connection//UML:AssociationEnd//UML:TaggedValue[@tag[matches(., "^(dest|source)style$")] and @value[contains(., "Navigable=Unspecified;")]])
                        )
                ]
        ]//UML:TaggedValue[@tag eq "sequenceNumber"]
};

(: Create a new result element :)
mod-fr:new-result($test-num, $pass-msg, $fail-msg, local:assert(/))