source: mauRepo/ISO19136-AnxE/test-007.xq @ 8191

xquery version "1.0";
(:~~~~~~~~~~~~~~~~~~~~~~~~~~ Conformance Test  ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
Test Number:    007
Description:    Asserts unique @xmi.id values in the XMI file
Reference:              An apparent bug in EA export can duplicate tagged values
                                for the root package. It may not be a 'bug' per se as it 
                                seems to have appeared in the GeoSciML model only after
                                manual user errors with synchrnonization of dependent packages.
                                For this reason it's worth including a test for it.
~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~:)

import module namespace mod-fr = "urn:local-module:ISO19136-V3.2-AnxE_XMI-V1.1:framework"
at "#{ROOT_URL}ISO19136-AnxE/modules/module-framework-functions.xq";

import module namespace mod-xp = "urn:local-module:ISO19136-V3.2-AnxE_XMI-V1.1:xmi-proc"
at "#{ROOT_URL}ISO19136-AnxE/modules/module-xproc-functions.xq";

declare namespace UML   = "omg.org/UML1.3";
declare namespace cr    = "http://ndg.service.newmoon.conftest-result/1.0";

(: Declare local variables, particular to this test :)
declare variable $test-num as xs:integer := 7;
declare variable $pass-msg as xs:string := "Each element in the XMI document does have a unique value of @xmi.id.";
declare variable $fail-msg as xs:string := "Model element has non-unique @xmi.id as follow:";

(:
        Declare the local assert function which defines a postive condition for pass.

        #EditedBy:      Krupali Patel
        #Note:          Improved diagnostic message.
:)
declare function local:assert($doc-root as node()?) as node()?
{
        let $fail := (
                for $dup in mod-xp:get-duplicates($doc-root//@xmi.id)
                return 
                        if ($dup eq "") then
                                <cr:message>@xmi.id = NULL (i.e. &quot;&quot;).</cr:message>
                        else
                                <cr:message>{ concat("@xmi.id = &quot;", $dup, "&quot;.") }</cr:message>
        )
        return
                if (empty($fail)) then ()
                else
                        <cr:fail>
                                <cr:messages>{ $fail }</cr:messages>
                        </cr:fail>
};

(: Create a new result element :)
mod-fr:new-result($test-num, $pass-msg, $fail-msg, local:assert(/))